Форум 1С
Программистам, бухгалтерам, администраторам, пользователям
Задай вопрос - получи решение проблемы
28 мар 2024, 16:40

Как создать внешнюю обработку для типовой конфигурации [Создать внешнюю обработку] [Дополнительные обработки]

Автор MuI_I_Ika, 04 дек 2015, 16:50

0 Пользователей и 1 гость просматривают эту тему.

MuI_I_Ika

Раздел конфигурирования
Прикладные объекты
Сразу оговорюсь, данный материал больше подходит для конфигураций, разрабатываемых на управляемых формах. Тем не менее общие принципы одинаковы для всех форм.

Для создания внешней обработки или отчета вам достаточно в конфигураторе выбрать меню Файл/Новый и выбрать вид обработку или отчет. После создания обработки впринципе ей уже можно пользоваться. Но для того чтобы подключить ее в типовую конфигурацию в качестве дополнительной обработки или отчета этого недостаточно.

Для этого вы должны в модуль обработки прописать несколько процедур. Общий их смысл сводится к тому, что вы даете понять конфигурации что это за обработка (отбработка, отчет, печатная форма, заполнение табличной части и т.д.), так же вы указываете в какой подсистеме она должна находиться.

Ниже этот код приведен. Для своей обработки вам нужно поменять несколько параметров.

Ну прежде всего это версия и название обработки, а так же название команды. Как я уже писал нужно указать подсистему, где она будет размещена или конкретный объект (справочник, документ).
Так же вид обработки, и режим использования. Безопасный режим не позволяет производить изменения в базе данных.

Функция СведенияОВнешнейОбработке() Экспорт
    // Объявим переменную, в которой мы сохраним и вернем "наружу" необходимые данные
    ПараметрыРегистрации = Новый Структура;

    // Объявим еще одну переменную, которая нам потребуется ниже
    МассивНазначений = Новый Массив;
   
    // Первый параметр, который мы должны указать - это какой вид обработки системе должна зарегистрировать.
    // Допустимые типы: ДополнительнаяОбработка, ДополнительныйОтчет, ЗаполнениеОбъекта, Отчет, ПечатнаяФорма, СозданиеСвязанныхОбъектов
    ПараметрыРегистрации.Вставить("Вид", "ДополнительнаяОбработка");

    // Теперь нам необходимо передать в виде массива имен, к чему будет подключена наша ВПФ
    // Имейте ввиду, что можно задать имя в таком виде: Документ.* - в этом случае обработка будет подключена ко всем документам в системе,
    // которые поддерживают механизм ВПФ
    МассивНазначений.Добавить("Подсистемы.РегламентированныйУчет");
    ПараметрыРегистрации.Вставить("Назначение", МассивНазначений);
   
    // Теперь зададим имя, под которым ВПФ будет зарегистрирована в справочнике внешних обработок
    ПараметрыРегистрации.Вставить("Наименование", "Анализ отрицательных остатков по регистрам");
   
    // Зададим право обработке на использование безопасного режима. Более подробно можно узнать в справке к платформе (метод УстановитьБезопасныйРежим)
    ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);

    // Следующие два параметра играют больше информационную роль, т.е. это то, что будет видеть пользователь в информации к обработке
    ПараметрыРегистрации.Вставить("Версия", "1.0");   
    ПараметрыРегистрации.Вставить("Информация", "Анализ отрицательных остатков по регистрам");
   
    // Создадим таблицу команд (подробнее смотрим ниже)
    ТаблицаКоманд = ПолучитьТаблицуКоманд();
   
    // Добавим команду в таблицу
ДобавитьКоманду(ТаблицаКоманд, "Анализ отрицательных остатков по регистрам", "Анализ отрицательных остатков по регистрам", "ОткрытиеФормы");
   
    // Сохраним таблицу команд в параметры регистрации обработки
    ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);
   
    // Теперь вернем системе наши параметры
    Возврат ПараметрыРегистрации;
КонецФункции

Функция ПолучитьТаблицуКоманд()

   // Создадим пустую таблицу команд и колонки в ней
   Команды = Новый ТаблицаЗначений;

   // Как будет выглядеть описание печатной формы для пользователя
   Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));

   // Имя нашего макета, что бы могли отличить вызванную команду в обработке печати
   Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));

   // Тут задается, как должна вызваться команда обработки
   // Возможные варианты:
   // - ОткрытиеФормы - в этом случае в колонке идентификатор должно быть указано имя формы, которое должна будет открыть система
   // - ВызовКлиентскогоМетода - вызвать клиентскую экспортную процедуру из модуля формы обработки
   // - ВызовСерверногоМетода - вызвать серверную экспортную процедуру из модуля объекта обработки
   Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));

   // Следующий параметр указывает, необходимо ли показывать оповещение при начале и завершению работы обработки. Не имеет смысла при открытии формы
   Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));

   // Для печатной формы должен содержать строку ПечатьMXL
   Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));
   Возврат Команды;
КонецФункции

Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")
// Добавляем команду в таблицу команд по переданному описанию.
  // Параметры и их значения можно посмотреть в функции ПолучитьТаблицуКоманд
  НоваяКоманда = ТаблицаКоманд.Добавить();
  НоваяКоманда.Представление = Представление;
  НоваяКоманда.Идентификатор = Идентификатор;
  НоваяКоманда.Использование = Использование;
  НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
  НоваяКоманда.Модификатор = Модификатор;

КонецПроцедуры

Теги:

Похожие темы (1)

Рейтинг@Mail.ru

Поиск